Amigo vi na sua planilha que você já seguiu os procedimentos do vídeo do link abaixo:
https://www.youtube.com/watch?v=s33FIzSQOdU
o que não deu certo ou o que você gostaria de fazer, se for trocar a imagem de acordo com um texto específico é so seguir o procedimento desse outro link abaixo, fica ai a dica:
https://www.youtube.com/watch?v=bQiAnZDidPE

Abraços.

RMC,
interessante o video,
mas no meu caso, voce viu como funciona o meu cadastro? Ele quando coloca a linha cadastrada par baixo ele não leva a imagem... Quando cadastro ela aparece, mas quando entra outra ela nao vai para baixo... Entende? Não sei se tem uma outra maneira de fazer... Como falei sou muito novo no excel..
Obrigado
José Octavio.

De uma olhada em http://www.planilhando.com.br/forum/viewtopic.php?f=20&t=18053&hilit=%2Aorden%2A&start=10, talvez lhe auxilie

Grande Reinaldo... nao estou usando VBA... como farei isso na minha humilde Planilha...???

Efetuar o que pretende, sem vb, teria que incluir um controle imagem para cada linha onde haverá bandeira, e uma definição para cada. Creio ficar inviavel

não sei como fazer isso...

Se quiser experimentar este código no lugar do seu, coloque o nome do país em 'H16' da planilha "Cadastro".
Vincule o código ao botão "Cadastrar" existente na planilha "Cadastro".
O código replica os dados na planilha "Lista de Cedulas Nacionais", cola cópia da bandeira do país escolhido, limpa os campos de origem.

Sub CadastraProdutosV2()
 Dim LR As Long, cell As Range, k As Long, b As Long, fig As Shape
  Application.ScreenUpdating = False
  With Sheets("Lista de Cedulas Nacionais")
   LR = .Cells(Rows.Count, 2).End(3).Row
    For Each cell In Range("E6,E8,E10,E12,E14,E16,H6,H8,H10,H12,H14,H16")
     .Cells(LR + 1, k + 2) = cell.Value
      k = k + 1
    Next cell
     b = Sheets("Planilha1").[B:B].Find([H16]).Row
    For Each fig In Sheets("Planilha1").Shapes
      If Not Intersect(fig.TopLeftCell, Sheets("Planilha1").Cells(b, 3)) Is Nothing Then
       fig.Copy
       .Cells(LR + 1, k + 2).PasteSpecial
      End If
    Next
  End With
  Range("E6,E8,E10,E12,E14,E16,H6,H8,H10,H12,H14,H16").Value = ""
  Application.ScreenUpdating = True
End Sub

Voce é fera... ficou show... So não esta mais colocando em ordem de codigo, e a bandeira nao centraliza...

So não esta mais colocando em ordem de codigo,
O que você quer dizer com "ordem de codigo"

e a bandeira nao centraliza...
O que acha de deixarmos a bandeira do tamanho da célula?

Organizar a planilha em ordem crescente pelos Codigos na coluna "B" ( C-009, C-010)... esta ficando conforme cadastro... Eu falo tipo um filtro... Poderia ser deixar a Bandeira do tamanho da celula sim...

Veja se melhorou.
Inclui comandos para ordenar em ordem crescente e centralizar a bandeira. Achei melhor a sua ideia de centralizar, pois ajustando a bandeira para o tamanho da célula uma encosta na outra e a aparência não fica legal.
Na planilha "Lista de Cedulas Nacionais" a partir da linha 6 ajuste todas as linhas com igual altura (deixe com altura maior do que a altura das bandeiras que estão na "Planilha1") e ajuste a largura da coluna 'N' (deixe com largura maior do que a largura das bandeiras que estão na "Planilha1").

Sub CadastraProdutosV3()
 Dim LR As Long, cell As Range, k As Long, b As Long, fig As Shape
  Application.ScreenUpdating = False
  With Sheets("Lista de Cedulas Nacionais")
   LR = .Cells(Rows.Count, 2).End(3).Row: If LR < 5 Then LR = 5
    For Each cell In Range("E6,E8,E10,E12,E14,E16,H6,H8,H10,H12,H14,H16")
     .Cells(LR + 1, k + 2) = cell.Value
      k = k + 1
    Next cell
     b = Sheets("Planilha1").[B:B].Find([H16]).Row
     Sheets("Planilha1").Cells(b, 3).Copy .Cells(LR + 1, k + 2)
     Set fig = .Shapes(.Shapes.Count)
      With .Cells(LR + 1, k + 2)
       fig.Left = .Left + ((.Width - fig.Width) / 2)
       fig.Top = .Top + ((.Height - fig.Height) / 2)
      End With
   .Range("B6:N" & LR + 1).Sort Key1:=.[B6], Order1:=xlAscending
  End With
  Range("E6,E8,E10,E12,E14,E16,H6,H8,H10,H12,H14,H16").Value = ""
  Application.ScreenUpdating = True
End Sub

Gostaria de agradecer mais uma vez a todos que tentaram encontrar uma solução para mim. Um agradecimento em especial a Osvaldomp, muito fera você... Ficou perfeito, melhor do que eu esperava...